Gecko [ christianhealingcodes.com ]

Name	Size	Permission	Date
config_data	6.97 KB	-r-xr-xr-x	2021-03-02 21:02
crc32	1.02 KB	-r-xr-xr-x	2021-03-02 21:01
crontab	1.81 MB	-rwxr-xr-x	2026-04-01 04:35
dbilogstrip	1.35 KB	-r-xr-xr-x	2021-03-02 21:01
dbiprof	6.06 KB	-r-xr-xr-x	2021-03-02 21:01
dbiproxy	5.27 KB	-r-xr-xr-x	2021-03-02 21:01
ea-php54	3.91 MB	-rwxr-xr-x	2026-03-19 03:55
ea-php55	4.01 MB	-rwxr-xr-x	2026-03-19 04:05
ea-php56	4.02 MB	-rwxr-xr-x	2026-03-19 03:51
ea-php70	3.91 MB	-rwxr-xr-x	2026-03-19 04:04
ea-php71	4.08 MB	-rwxr-xr-x	2026-03-19 04:01
ea-php72	4.32 MB	-rwxr-xr-x	2026-03-19 04:07
ea-php73	4.71 MB	-rwxr-xr-x	2026-03-19 04:08
ea-php74	6.09 MB	-rwxr-xr-x	2026-03-19 03:57
ea-php80	6.67 MB	-rwxr-xr-x	2026-03-18 23:17
ea_convert_php_ini	39.85 KB	-rwxr-xr-x	2026-03-18 22:43
ea_current_to_profile	8.31 KB	-rwxr-xr-x	2026-03-18 22:43
ea_install_profile	7.1 KB	-rwxr-xr-x	2026-03-18 22:43
ea_sync_user_phpini_settings	6.73 KB	-rwxr-xr-x	2026-03-18 22:43
enc2xs	40.69 KB	-r-xr-xr-x	2021-03-02 21:02
encguess	2.92 KB	-r-xr-xr-x	2021-03-02 21:02
env_parallel	4.49 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.ash	14.08 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.bash	14.25 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.csh	5.11 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.dash	14.08 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.fish	6.34 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.ksh	13.4 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.mksh	13.46 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.pdksh	5.85 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.sh	14.06 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.tcsh	5.11 KB	-rwxr-xr-x	2021-01-23 21:37
env_parallel.zsh	13.49 KB	-rwxr-xr-x	2021-01-23 21:37
filescout	45.14 KB	-r-x------	2019-05-15 20:49
gpgmailtunl	6.3 KB	-r-xr-xr-x	2021-03-02 21:01
instmodsh	4.1 KB	-r-xr-xr-x	2021-01-13 19:43
json_pp	4.78 KB	-r-xr-xr-x	2021-03-02 21:01
json_xs	6.93 KB	-r-xr-xr-x	2021-01-13 19:43
logscout	5.38 KB	-r-x------	2019-05-15 20:49
lsphp	937 B	-rwxr-xr-x	2025-04-01 16:34
lwp-download	10.05 KB	-r-xr-xr-x	2021-03-02 21:02
lwp-dump	2.65 KB	-r-xr-xr-x	2021-03-02 21:02
lwp-mirror	2.36 KB	-r-xr-xr-x	2021-03-02 21:02
lwp-request	15.82 KB	-r-xr-xr-x	2021-03-02 21:02
niceload	32.36 KB	-rwxr-xr-x	2021-01-23 21:37
parallel	391.58 KB	-rwxr-xr-x	2021-01-23 21:37
parcat	3.93 KB	-rwxr-xr-x	2021-01-23 21:37
parset	3.93 KB	-rwxr-xr-x	2021-01-23 21:37
parsort	6.6 KB	-rwxr-xr-x	2021-01-23 21:37
passwd	3.47 MB	-rwxr-xr-x	2026-04-01 04:35
pear	935 B	-rwxr-xr-x	2025-04-01 16:34
php	933 B	-rwxr-xr-x	2025-04-01 16:34
piconv	8.08 KB	-r-xr-xr-x	2021-03-02 21:02
prove	13.24 KB	-r-xr-xr-x	2021-03-02 21:01
ptar	3.39 KB	-r-xr-xr-x	2021-03-02 21:01
ptardiff	2.49 KB	-r-xr-xr-x	2021-03-02 21:01
ptargrep	4.2 KB	-r-xr-xr-x	2021-03-02 21:01
sem	391.58 KB	-rwxr-xr-x	2021-01-23 21:37
shasum	9.66 KB	-r-xr-xr-x	2021-03-02 21:01
sql	30.91 KB	-rwxr-xr-x	2021-01-23 21:37
test-yaml	1 KB	-r-xr-xr-x	2021-03-02 21:02
whodat	85.81 KB	-r-x------	2025-02-26 19:26
wp	5.31 MB	-rwxr-xr-x	2021-01-13 19:47

Rename

#!/usr/bin/perl
##############################################################################
# Tool for using regular expressions against the contents of files in a tar
# archive.  See 'ptargrep --help' for more documentation.
#

BEGIN { pop @INC if $INC[-1] eq '.' }
use strict;
use warnings;

use Pod::Usage   qw(pod2usage);
use Getopt::Long qw(GetOptions);
use Archive::Tar qw();
use File::Path   qw(mkpath);

my(%opt, $pattern);

if(!GetOptions(\%opt,
    'basename|b',
    'ignore-case|i',
    'list-only|l',
    'verbose|v',
    'help|?',
)) {
    pod2usage(-exitval => 1,  -verbose => 0);
}

pod2usage(-exitstatus => 0, -verbose => 2) if $opt{help};

pod2usage(-exitval => 1,  -verbose => 0,
    -message => "No pattern specified",
) unless @ARGV;
make_pattern( shift(@ARGV) );

pod2usage(-exitval => 1,  -verbose => 0,
    -message => "No tar files specified",
) unless @ARGV;

process_archive($_) foreach @ARGV;

exit 0;

sub make_pattern {
    my($pat) = @_;

if($opt{'ignore-case'}) {
        $pattern = qr{(?im)$pat};
    }
    else {
        $pattern = qr{(?m)$pat};
    }
}

sub process_archive {
    my($filename) = @_;

_log("Processing archive: $filename");
    my $next = Archive::Tar->iter($filename);
    while( my $f = $next->() ) {
        next unless $f->is_file;
        match_file($f) if $f->size > 0;
    }
}

sub match_file {
    my($f)   = @_;
    my $path = $f->name;
    my $prefix = $f->prefix;
    if (defined $prefix) {
        $path = File::Spec->catfile($prefix, $path);
    }

_log("filename: %s  (%d bytes)", $path, $f->size);

my $body = $f->get_content();
    if($body !~ $pattern) {
        _log("  no match");
        return;
    }

if($opt{'list-only'}) {
        print $path, "\n";
        return;
    }

save_file($path, $body);
}

sub save_file {
    my($path, $body) = @_;

_log("  found match - extracting");
    my($fh);
    my($dir, $file) = $path =~ m{\A(?:(.*)/)?([^/]+)\z};
    if($dir and not $opt{basename}) {
        _log("  writing to $dir/$file");
        $dir =~ s{\A/}{./};
        mkpath($dir) unless -d $dir;
        open $fh, '>', "$dir/$file" or die "open($dir/$file): $!";
    }
    else {
        _log("  writing to ./$file");
        open $fh, '>', $file or die "open($file): $!";
    }
    print $fh $body;
    close($fh);
}

sub _log {
    return unless $opt{verbose};
    my($format, @args) = @_;
    warn sprintf($format, @args) . "\n";
}

__END__

=head1 NAME

ptargrep - Apply pattern matching to the contents of files in a tar archive

=head1 SYNOPSIS

ptargrep [options] <pattern> <tar file> ...

Options:

--basename|-b     ignore directory paths from archive
   --ignore-case|-i  do case-insensitive pattern matching
   --list-only|-l    list matching filenames rather than extracting matches
   --verbose|-v      write debugging message to STDERR
   --help|-?         detailed help message

=head1 DESCRIPTION

This utility allows you to apply pattern matching to B<the contents> of files
contained in a tar archive.  You might use this to identify all files in an
archive which contain lines matching the specified pattern and either print out
the pathnames or extract the files.

The pattern will be used as a Perl regular expression (as opposed to a simple
grep regex).

Multiple tar archive filenames can be specified - they will each be processed
in turn.

=head1 OPTIONS

=over 4

=item B<--basename> (alias -b)

When matching files are extracted, ignore the directory path from the archive
and write to the current directory using the basename of the file from the
archive.  Beware: if two matching files in the archive have the same basename,
the second file extracted will overwrite the first.

=item B<--ignore-case> (alias -i)

Make pattern matching case-insensitive.

=item B<--list-only> (alias -l)

Print the pathname of each matching file from the archive to STDOUT.  Without
this option, the default behaviour is to extract each matching file.

=item B<--verbose> (alias -v)

Log debugging info to STDERR.

=item B<--help> (alias -?)

Display this documentation.

=back

=head1 COPYRIGHT

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=cut